neo4j使用详解（六、cypher即时时间函数语法——最全参考）

  • 开发
  • 16

请添加图片描述

Neo4j系列导航：
neo4j及简单实践
cypher语法基础
cypher插入语法
cypher插入语法
cypher查询语法
cypher通用语法
cypher函数语法

6.时间函数-即时类型

表示具体的时刻的时间类型函数

6.1.date函数

年-月-日时间函数： yyyy-mm-dd

6.1.1.获取date

  • date()： 获取当前时间，如果未指定时区参数，则将使用本地时区 date([{timezone}])

    return date() as currentDate // 返回值2024-04-01
    return date({timezone: 'America/Los Angeles'}) // 返回值2024-04-01

  • date.transaction()： 使用transaction时返回当前date。对于同一事务中的每次调用，该值都是相同的 date.transaction([{timezone}])

    return date.transaction() as currentDate // 返回值2024-04-01

  • date.statement()： 使用statement返回当前date值。对于同一语句中的每次调用，该值都相同。但是，同一事务中的不同语句可能会产生不同的值 date.statement([{timezone}])

    return date.statement() as currentDate // 返回值2024-04-01

  • date.realtime()： 使用date返回当前值realtime。该值将是系统的实时时钟。 （系统时间）date.realtime([{timezone}])

    return date.realtime() as currentDate // 返回值2024-04-01

6.1.2.创建date

  • 创建 年-月-日： 返回一个date值，其中包含指定的年、月、日 date({year [, month, day]})

    unwind [date({year: 1984, month: 10, day: 11}),date({year: 1984, month: 10}),date({year: 1984})] as theDate return theDate // 返回值1984-10-11, 1984-10-01, 1984-01-01

  • 创建 年-周-日： date({year [, week, dayOfWeek]})

    unwind [date({year: 1984, week: 10, dayOfWeek: 3}), date({year: 1984, week: 10}),date({year: 1984})] as theDate return theDate // 返回值1984-03-07, 1984-03-05, 1984-01-01

  • 创建 年-季度-日： date({year [, quarter, dayOfQuarter]})

    unwind [date({year: 1984, quarter: 3, dayOfQuarter:45}),date({year: 1984, quarter: 3}),date({year: 1984})] as theDate return theDate // 返回值1984-08-14, 1984-07-01, 1984-01-01

  • 创建 年-日： date({year [, ordinalDay]})

    unwind [date({year: 1984, ordinalDay: 202}),date({year: 1984})] AS theDate return theDate // 返回值1984-07-20, 1984-01-01

  • 创建 根据时间字符串： date(temporalValue)

    unwind [date('2015-07-21'),date('2015-07'),date('201507'),date('2015-W30-2'),date('2015202'),date('2015')] as theDate return theDate // 返回值2015-07-21, 2015-07-01, 2015-07-01, 2015-07-21, 2015-07-21, 2015-01-01

  • 创建 使用其他时间组件： date({date [, year, month, day, week, dayOfWeek, quarter, dayOfQuarter, ordinalDay]})

    unwind [ date({year: 1984, month: 11, day: 11}), localdatetime({year: 1984, month: 11, day: 11, hour: 12, minute: 31, second: 14}), datetime({year: 1984, month: 11, day: 11, hour: 12, timezone: '+01:00'}) ] as dd return date({date: dd}) as dateOnly, date({date: dd, day: 28}) as dateDay

6.1.3.分割date

返回date通过在指定组件边界（由作为参数传递给函数的截断单元表示）处最近的先前时间点处截断指定瞬时瞬时值而获得的值。
date.truncate(unit [, temporalInstantValue [, mapOfComponents ] ])

参数 含义
unit 计算结果为以下string值之一的字符串表达式：'millennium', 'century', 'decade', 'year', 'weekYear', 'quarter', 'month', 'week', 'day'
temporalInstantValue 以下类型之一的表达式：ZONED DATETIME, LOCAL DATETIME, DATE
mapOfComponents 计算包含小于 的分量的映射的表达式unit

实例：

with datetime({
    year: 2017, month: 11, day: 11,
    hour: 12, minute: 31, second: 14, nanosecond: 645876123,
    timezone: '+01:00'
  }) as d
  return
  date.truncate('millennium', d) as truncMillenium,
  date.truncate('century', d) as truncCentury,
  date.truncate('decade', d) AS truncDecade,
  date.truncate('year', d, {day: 5}) AS truncYear,
  date.truncate('weekYear', d) as truncWeekYear,
  date.truncate('quarter', d) as truncQuarter,
  date.truncate('month', d) as truncMonth,
  date.truncate('week', d, {dayOfWeek: 2}) as truncWeek,
  date.truncate('day', d) as truncDay

结果：

千禧年节 截断世纪 截断十年 截断年份 截断周年 截断季度 截断月份 截断周 截断日
2000-01-01 2000-01-01 2010-01-01 2017-01-05 2017-01-02 2017-10-01 2017-11-01 2017-11-07 2017-11-11

6.2.datetime函数

年-月-日 时:分:秒:毫秒时间函数：yyyy-mm-ddThh:MM:SS:sssZ

6.2.1.获取datetime

  • datetime(): datetime([{timezone}])

    return datetime() //2024-04-01T10:02:28.192Z
    return datetime({timezone: 'America/Los Angeles'}) // 2024-04-01T03:02:28.238-07:00[America/Los_Angeles]

  • datetime.transaction(): datetime.transaction([{timezone}])

    return datetime.transaction() //2024-04-01T18:02:28.290Z
    RETURN datetime.transaction('America/Los Angeles') //2024-04-01T03:02:28.338-07:00[America/Los_Angeles]

  • datetime.statement(): datetime.statement([{timezone}])

    return datetime.statement() //2024-04-01T10:02:28.395Z

  • datetime.realtime(): datetime.realtime([{timezone}])

    return datetime.realtime() //2024-04-01T10:02:28.494444Z

6.2.2.创建datatime时间

datetime()返回一个带时区的datetime值，其中包含指定的年、月、日、时、分、秒、毫秒、微秒、纳秒和时区组件值。

  • 创建 年-月-日 时:分:秒： datetime({year [, month, day, hour, minute, second, millisecond, microsecond, nanosecond, timezone]})
    实例：

    unwind[
	datetime({year: 1984, month: 10, day: 11, hour: 12, minute: 31, second: 14, millisecond: 123, microsecond: 456, nanosecond: 789}),
	datetime({year: 1984, month: 10, day: 11, hour: 12, minute: 31, second: 14, millisecond: 645, timezone: '+01:00'}),
	datetime({year: 1984, month: 10, day: 11, hour: 12, minute: 31, second: 14, nanosecond: 645876123, timezone: 'Europe/Stockholm'}),
	datetime({year: 1984, month: 10, day: 11, hour: 12, minute: 31, second: 14, timezone: '+01:00'}),
	datetime({year: 1984, month: 10, day: 11, hour: 12, minute: 31, second: 14}),
	datetime({year: 1984, month: 10, day: 11, hour: 12, minute: 31, timezone: 'Europe/Stockholm'}),
	datetime({year: 1984, month: 10, day: 11, hour: 12, timezone: '+01:00'}),
	datetime({year: 1984, month: 10, day: 11, timezone: 'Europe/Stockholm'})
] as theDate return theDate

    结果：

    返回值
    1984-10-11T12:31:14.123456789Z
    1984-10-11T12:31:14.645+01:00
    1984-10-11T12:31:14.645876123+01:00[Europe/Stockholm]
    1984-10-11T12:31:14+01:00
    1984-10-11T12:31:14Z
    1984-10-11T12:31+01:00[Europe/Stockholm]
    1984-10-11T12:00+01:00
    1984-10-11T00:00+01:00[Europe/Stockholm]

  • 创建 年-周-日： datetime({year [, week, dayOfWeek, hour, minute, second, millisecond, microsecond, nanosecond, timezone]})
    实例：

    unwind[
	datetime({year: 1984, week: 10, dayOfWeek: 3, hour: 12, minute: 31, second: 14, millisecond: 645}),
	datetime({year: 1984, week: 10, dayOfWeek: 3, hour: 12, minute: 31, second: 14, microsecond: 645876, timezone: '+01:00'}),
	datetime({year: 1984, week: 10, dayOfWeek: 3, hour: 12, minute: 31, second: 14, nanosecond: 645876123, timezone: 'Europe/Stockholm'}),
	datetime({year: 1984, week: 10, dayOfWeek: 3, hour: 12, minute: 31, second: 14, timezone: 'Europe/Stockholm'}),
	datetime({year: 1984, week: 10, dayOfWeek: 3, hour: 12, minute: 31, second: 14}),
	datetime({year: 1984, week: 10, dayOfWeek: 3, hour: 12, timezone: '+01:00'}),
	datetime({year: 1984, week: 10, dayOfWeek: 3, timezone: 'Europe/Stockholm'})
] as theDate return theDate

    结果：

    返回值
    1984-03-07T12:31:14.645Z
    1984-03-07T12:31:14.645876+01:00
    1984-03-07T12:31:14.645876123+01:00[Europe/Stockholm]
    1984-03-07T12:31:14+01:00[Europe/Stockholm]
    1984-03-07T12:31:14Z
    1984-03-07T12:00+01:00
    1984-03-07T00:00+01:00[Europe/Stockholm]

  • 创建 年-季度-日： datetime({year [, quarter, dayOfQuarter, hour, minute, second, millisecond, microsecond, nanosecond, timezone]})
    实例：

    unwind[
	datetime({year: 1984, quarter: 3, dayOfQuarter: 45, hour: 12, minute: 31, second: 14, microsecond: 645876}),
	datetime({year: 1984, quarter: 3, dayOfQuarter: 45, hour: 12, minute: 31, second: 14, timezone: '+01:00'}),
	datetime({year: 1984, quarter: 3, dayOfQuarter: 45, hour: 12, timezone: 'Europe/Stockholm'}),
	datetime({year: 1984, quarter: 3, dayOfQuarter: 45})
] as theDate return theDate

    结果：

    返回值
    1984-08-14T12:31:14.645876Z
    1984-08-14T12:31:14+01:00
    1984-08-14T12:00+02:00[Europe/Stockholm]
    1984-08-14T00:00Z

  • 创建 年-日： datetime({year [, ordinalDay, hour, minute, second, millisecond, microsecond, nanosecond, timezone]})
    实例：

    unwind[
	datetime({year: 1984, ordinalDay: 202, hour: 12, minute: 31, second: 14, millisecond: 645}),
	datetime({year: 1984, ordinalDay: 202, hour: 12, minute: 31, second: 14, timezone: '+01:00'}),
	datetime({year: 1984, ordinalDay: 202, timezone: 'Europe/Stockholm'}),
	datetime({year: 1984, ordinalDay: 202})
] as theDate return theDate

    结果：

    返回值
    1984-07-20T12:31:14.645Z
    1984-07-20T12:31:14+01:00
    1984-07-20T00:00+02:00[Europe/Stockholm]
    1984-07-20T00:00Z

  • 创建 根据时间字符串: datetime(temporalValue)
    实例：

    unwind[
	datetime('2015-07-21T21:40:32.142+0100'),
	datetime('2015-W30-2T214032.142Z'),
	datetime('2015T214032-0100'),
	datetime('20150721T21:40-01:30'),
	datetime('2015-W30T2140-02'),
	datetime('2015202T21+18:00'),
	datetime('2015-07-21T21:40:32.142[Europe/London]'),
	datetime('2015-07-21T21:40:32.142-04[America/New_York]')
] as theDate return theDate

    结果：

    返回值
    2015-07-21T21:40:32.142+01:00
    2015-07-21T21:40:32.142Z
    2015-01-01T21:40:32-01:00
    2015-07-21T21:40-01:30
    2015-07-20T21:40-02:00
    2015-07-21T21:00+18:00
    2015-07-21T21:40:32.142+01:00[Europe/London]
    2015-07-21T21:40:32.142-04:00[America/New_York]

  • 创建 使用其他时间组件：
    datetime({datetime [, year, ..., timezone]}) | datetime({date [, year, ..., timezone]}) | datetime({time [, year, ..., timezone]}) | datetime({date, time [, year, ..., timezone]})
    实例：

    with date({year: 1984, month: 10, day: 11}) as dd
return
datetime({date: dd, hour: 10, minute: 10, second: 10}) as dateHHMMSS,
datetime({date: dd, hour: 10, minute: 10, second: 10, timezone:'+05:00'}) as dateHHMMSSTimezone,
datetime({date: dd, day: 28, hour: 10, minute: 10, second: 10}) as dateDDHHMMSS,
datetime({date: dd, day: 28, hour: 10, minute: 10, second: 10, timezone:'Pacific/Honolulu'}) as dateDDHHMMSSTimezone

    结果：

    dateHHMMSS dateHHMMSSTimezone dateDDHHMMSS dateDDHHMMSSTimezone
    1984-10-11T10:10:10Z 1984-10-11T10:10:10+05:00 1984-10-28T10:10:10Z 1984-10-28T10:10:10-10:00[Pacific/Honolulu]

  • 创建 根据时间戳： datetime({ epochSeconds | epochMillis })

    return datetime({epochSeconds: timestamp() / 1000, nanosecond: 23}) //2022-06-14T10:02:30.000000023Z
    return datetime({epochMillis: 424797300000}) //1983-06-18T15:15Z

6.2.3.分割datetime

返回datetime通过在指定组件边界（由作为参数传递给函数的截断单元表示）处最近的先前时间点处截断指定瞬时值而获得的值。
datetime.truncate(unit [, temporalInstantValue [, mapOfComponents ] ])

参数 含义
unit 求值为以下字符串之一的字符串表达式:‘millennium’、‘century’、‘decade’、‘year’、‘weekYear’、‘quarter’、‘month’、‘week’、‘day’、‘hour’、‘minute’、‘second’、‘millisecond’、‘microsecond’。
temporalInstantValue 以下类型之一的表达式：ZONED DATETIME, LOCAL DATETIME, DATE
mapOfComponents 求值为包含小于单位的组件的映射的表达式。在截断期间，可以使用键时区附加或覆盖时区。

实例：

with
  datetime({
    year:2017, month:11, day:11,
    hour:12, minute:31, second:14, nanosecond: 645876123,
    timezone: '+03:00'
  }) AS d
return
  datetime.truncate('millennium', d, {timezone: 'Europe/Stockholm'}) as truncMillenium,
  datetime.truncate('year', d, {day: 5}) as truncYear,
  datetime.truncate('month', d) as truncMonth,
  datetime.truncate('day', d, {millisecond: 2}) as truncDay,
  datetime.truncate('hour', d) as truncHour,
  datetime.truncate('second', d) as truncSecond

结果：

truncMillenium truncYear truncMonth truncDay truncHour truncSecond
2000-01-01T00:00+01:00[Europe/Stockholm] 2017-01-05T00:00+03:00 2017-11-01T00:00+03:00 2017-11-11T00:00:00.002+03:00 2017-11-11T12:00+03:00 2017-11-11T12:31:14+03:00

6.3.localdatetime函数

年-月-日 时:分:秒:毫秒时间函数：yyyy-mm-ddThh:MM:SS:sss

6.3.1.获取localdatetime

  • localdatetime(): localdatetime([{timezone}])

    return localdatetime() //2024-04-01T10:02:30.447
    return localdatetime({timezone: 'America/Los Angeles'}) // 2024-04-01T03:02:30.482

  • localdatetime.transaction(): localdatetime.transaction([{timezone}])

    return localdatetime.transaction() //2024-04-01T10:02:30.532

  • localdatetime.statement(): localdatetime.statement([{timezone}])

    return localdatetime.statement() //2024-04-01T10:02:30.570

  • localdatetime.realtime(): localdatetime.realtime([{timezone}])

    return localdatetime.realtime() //2024-04-01T10:02:30.647817
    return localdatetime.realtime('America/Los Angeles') //2024-04-01T03:02:30.691099

6.3.2.创建localdatetime

  • 创建 年-月-日:
    localdatetime({year [, month, day, hour, minute, second, millisecond, microsecond, nanosecond]})

    return 
  localdatetime({
    year: 1984, month: 10, day: 11,
    hour: 12, minute: 31, second: 14, millisecond: 123, microsecond: 456, nanosecond: 789
  }) as theDate
    返回值
    1984-10-11T12:31:14.123456789

  • 创建 年-周-日:
    localdatetime({year [, week, dayOfWeek, hour, minute, second, millisecond, microsecond, nanosecond]})

    return
localdatetime({
	year: 1984, week: 10, dayOfWeek: 3,
	hour: 12, minute: 31, second: 14, millisecond: 645
}) as theDate
    返回值
    1984-03-07T12:31:14.645

  • 创建 年-季-日:
    localdatetime({year [, quarter, dayOfQuarter, hour, minute, second, millisecond, microsecond, nanosecond]})

    return
localdatetime({
year: 1984, quarter: 3, dayOfQuarter: 45,
hour: 12, minute: 31, second: 14, nanosecond: 645876123
}) as theDate
    返回值
    1984-08-14T12:31:14.645876123

  • 创建 年-日:
    localdatetime({year [, ordinalDay, hour, minute, second, millisecond, microsecond, nanosecond]})

    return
localdatetime({
year: 1984, ordinalDay: 202,
hour: 12, minute: 31, second: 14, microsecond: 645876
}) as theDate
    返回值
    1984-07-20T12:31:14.645876

  • 创建 时间格式字符串: localdatetime(temporalValue)

    unwind [
	localdatetime('2015-07-21T21:40:32.142'),
	localdatetime('2015-W30-2T214032.142'),
	localdatetime('2015-202T21:40:32'),
	localdatetime('2015202T21')
	] as theDate
return theDate
    返回值
    2015-07-21T21:40:32.142
    2015-07-21T21:40:32.142
    2015-07-21T21:40:32
    2015-07-21T21:00

  • 创建 使用其他时间组件：
    localdatetime({datetime [, year, ..., nanosecond]}) | localdatetime({date [, year, ..., nanosecond]}) | localdatetime({time [, year, ..., nanosecond]}) | localdatetime({date, time [, year, ..., nanosecond]})
    实例1：

    with date({year: 1984, month: 10, day: 11}) as dd
return
	localdatetime({date: dd, hour: 10, minute: 10, second: 10}) as dateHHMMSS,
	localdatetime({date: dd, day: 28, hour: 10, minute: 10, second: 10}) as dateDDHHMMSS
    dateHHMMSS dateDDHHMMSS
    1984-10-11T10:10:10 1984-10-28T10:10:10

    实例2：

    WITH
  datetime({
    year: 1984, month: 10, day: 11,
    hour: 12,
    timezone: '+01:00'
  }) as dd
return
  localdatetime({datetime: dd}) as dateTime,
  localdatetime({datetime: dd, day: 28, second: 42}) as dateTimeDDSS
    dateTime dateTimeDDSS
    1984-10-11T12:00 1984-10-28T12:00:42

6.3.3.分割localdatetime

localdatetime.truncate(unit [, temporalInstantValue [, mapOfComponents ] ])
实例：

with
  localdatetime({
    year: 2017, month: 11, day: 11,
    hour: 12, minute: 31, second: 14, nanosecond: 645876123
  }) as d
return
  localdatetime.truncate('millennium', d) as truncMillenium,
  localdatetime.truncate('year', d, {day: 2}) as truncYear,
  localdatetime.truncate('month', d) as truncMonth,
  localdatetime.truncate('day', d) as truncDay,
  localdatetime.truncate('hour', d, {nanosecond: 2}) as truncHour,
  localdatetime.truncate('second', d) as truncSecond
truncMillenium truncYear truncMonth truncDay truncHour truncSecond
2000-01-01T00:00 2017-01-02T00:00 2017-11-01T00:00 2017-11-11T00:00 2017-11-11T12:00:00.000000002 2017-11-11T12:31:14

6.4.localtime函数

时:分:秒:毫秒时间函数：hh:MM:SS.sss

6.4.1.获取localtime

  • localtime(): localtime([{timezone}])

    return localtime() //10:02:30.447
    return localtime({timezone: 'America/Los Angeles'}) // 03:02:30.482

  • localtime.transaction(): localtime.transaction([{timezone}])

    return localtime.transaction() //10:02:30.532

  • localtime.statement(): localtime.statement([{timezone}])

    return localtime.statement() //10:02:30.570

  • localtime.realtime(): localtime.realtime([{timezone}])

    return localtime.realtime() //10:02:30.647817
    return localtime.realtime('America/Los Angeles') //03:02:30.691099

6.4.2.创建localtime

  • 创建localtime:
    localtime({hour [, minute, second, millisecond, microsecond, nanosecond]})

    unwind[
	localtime({hour: 12, minute: 31, second: 14, nanosecond: 789, millisecond: 123, microsecond: 456}),
	localtime({hour: 12, minute: 31, second: 14}),
	localtime({hour: 12})
] as theTime
return theTime
    返回值
    12:31:14.123456789
    12:31:14
    12:00

  • 创建 根据Time格式字符串: localtime(temporalValue)

    unwind[
	localtime('21:40:32.142'),
	localtime('214032.142'),
	localtime('21:40'),
	localtime('21')
] as theTime
return theTime
    返回值
    21:40:32.142
    21:40:32.142
    21:40
    21:00

  • 创建 使用其他时间组件： localtime({time [, hour, ..., nanosecond]})
    实例：

    with time({hour: 12, minute: 31, second: 14, microsecond: 645876, timezone: '+01:00'}) as tt
return
  localtime({time: tt}) as timeOnly,
  localtime({time: tt, second: 42}) as timeSS
    timeOnly timeSS
    12:31:14.645876 12:31:42.645876

6.4.3.分割localime

localtime.truncate(unit [, temporalInstantValue [, mapOfComponents ] ])
实例：

with time({hour: 12, minute: 31, second: 14, nanosecond: 645876123, timezone: '-01:00'}) as t
return
  localtime.truncate('day', t) as truncDay,
  localtime.truncate('hour', t) as truncHour,
  localtime.truncate('minute', t, {millisecond: 2}) as truncMinute,
  localtime.truncate('second', t) as truncSecond,
  localtime.truncate('millisecond', t) as truncMillisecond,
  localtime.truncate('microsecond', t) as truncMicrosecond
truncDay truncHour truncMinute truncSecond truncMillisecond truncMicrosecond
00:00:00 12:00:00 12:31:00.002000000 12:31:14 12:31:14.645000000 12:31:14.645876000

6.5.time函数

时:分:秒:毫秒时间函数：hh:MM:SS.sssZ

6.4.1.获取time

  • time(): time([{timezone}])

    return time() //10:02:30.447
    return time({timezone: 'America/Los Angeles'}) // 03:02:32.351-07:00

  • time.transaction(): localtime.transaction([{timezone}])

    return time.transaction() //10:02:30.532Z

  • time.statement(): localtime.statement([{timezone}])

    return time.statement() //10:02:30.570Z

  • time.realtime(): localtime.realtime([{timezone}])

    return time.realtime() //10:02:30.647817Z
    return time.realtime('America/Los Angeles') //03:02:32.351-07:00

6.4.2.创建time

  • 创建localtime:
    time({hour [, minute, second, millisecond, microsecond, nanosecond, timezone]})

    unwind[
	time({hour: 12, minute: 31, second: 14, millisecond: 123, microsecond: 456, nanosecond: 789}),
	time({hour: 12, minute: 31, second: 14, nanosecond: 645876123}),
	time({hour: 12, minute: 31, second: 14, microsecond: 645876, timezone: '+01:00'}),
	time({hour: 12, minute: 31, timezone: '+01:00'}),
	time({hour: 12, timezone: '+01:00'})
] as theTime
return theTime
    返回值
    12:31:14.123456789Z
    12:31:14.645876123Z
    12:31:14.645876000+01:00
    12:31:00+01:00
    12:00:00+01:00

  • 创建 根据Time格式字符串: time(temporalValue)

    unwind[
	time('21:40:32.142+0100'),
	time('214032.142Z'),
	time('21:40:32+01:00'),
	time('214032-0100'),
	time('21:40-01:30'),
	time('2140-00:00'),
	time('2140-02'),
	time('22+18:00')
	] as theTime
return theTime
    返回值
    21:40:32.142000000+01:00
    21:40:32.142000000Z
    21:40:32+01:00
    21:40:32-01:00
    21:40:00-01:30
    21:40:00Z
    21:40:00-02:00
    22:00:00+18:00

  • 创建 使用其他时间组件： time({time [, hour, ..., timezone]})
    实例：

    with localtime({hour: 12, minute: 31, second: 14, microsecond: 645876}) AS tt
return
  time({time: tt}) as timeOnly,
  time({time: tt, timezone: '+05:00'}) as timeTimezone,
  time({time: tt, second: 42}) as timeSS,
  time({time: tt, second: 42, timezone: '+05:00'}) as timeSSTimezone
    timeOnly timeTimezone timeSS timeSSTimezone
    12:31:14.645876Z 12:31:14.645876+05:00 12:31:42.645876Z 12:31:42.645876+05:00

6.4.3.分割localime

time.truncate(unit [, temporalInstantValue [, mapOfComponents ] ])
实例：

with time({hour: 12, minute: 31, second: 14, nanosecond: 645876123, timezone: '-01:00'}) as t
return 
  time.truncate('day', t) as truncDay,
  time.truncate('hour', t) as truncHour,
  time.truncate('minute', t) as truncMinute,
  time.truncate('second', t) as truncSecond,
  time.truncate('millisecond', t, {nanosecond: 2}) as truncMillisecond,
  time.truncate('microsecond', t) as truncMicrosecond
truncDay truncHour truncMinute truncSecond truncMillisecond truncMicrosecond
00:00:00-01:00 12:00:00-01:00 12:31:00-01:00 12:31:14-01:00 12:31:14.645000002-01:00 12:31:14.645876000-01:00
阅读全部

相关推荐

  4. neo4j-cypher语言使用

    2024-04-02 03:48:03       34 阅读

  5. neo4j查询语言Cypher详解(五)--apoc

    2024-04-02 03:48:03       37 阅读

  7. Neo4j图形数据库查询，Cypher语言详解

    2024-04-02 03:48:03       5 阅读

  9. neo4j的Cypher的语法记录

    2024-04-02 03:48:03       12 阅读

最近更新

  4. TCP协议是安全的吗?

    2024-04-02 03:48:03       16 阅读

  12. 阿里云服务器执行yum，一直下载docker-ce-stable失败

    2024-04-02 03:48:03       16 阅读

  13. 【Python教程】压缩PDF文件大小

    2024-04-02 03:48:03       15 阅读

  18. 通过文章id递归查询所有评论（xml）

    2024-04-02 03:48:03       18 阅读

热门阅读

  1. PHP8.3-ZTS版本安装流程以及添加扩展

    2024-04-02 03:48:03       20 阅读

  6. Linux命令基础

    2024-04-02 03:48:03       15 阅读

  10. 题解：CF1934A（Too Min Too Max）

    2024-04-02 03:48:03       20 阅读

  16. 【代码随想录】【动态规划】day39:不同路径

    2024-04-02 03:48:03       15 阅读

  20. EMF相关学习文档

    2024-04-02 03:48:03       12 阅读

  21. web服务应用术语

    2024-04-02 03:48:03       14 阅读

  28. 阿里巴巴实习面经

    2024-04-02 03:48:03       19 阅读

  29. 竞赛常考的知识点大总结(二)基础算法

    2024-04-02 03:48:03       19 阅读

  30. vue3中computed详解

    2024-04-02 03:48:03       14 阅读