esp8266接入阿里云物联网平台(MQTT客户端直连)

这里不介绍怎么进行详细开发，只讲如何快速实现接入物联网平台，具体操作可以先看文档阿里云

我们这次的实验用的是8266的Node-MCU开发板，通过8266接入阿里云平台，然后使用MQTT.fx模拟远程控制的客户端(手机、电脑)，远程控制8266板载的LED亮灭。

1、创建设备(默认你们已经注册好账号了)

 2、添加设备

我创建了如图所示的设备

 3、激活设备(重点)

你们新创建的设备一定和我上图的LED2一样是未激活状态，因为你们的设备还没有接入到阿里云平台。现在就操作一下把MQTT.fx接入到平台上。

先下载MQTT.fx客户端mqttfx-1.7.1-windows-x64.exe_免费高速下载|百度网盘-分享无限制 (baidu.com)

安装完成后打开软件

 ProfileName

MQTT(设备名字)

Broker Address

格式： {YourProductKey}.iot-as-mqtt.{region}.aliyuncs.com
其中，{YourProductKey}这个我就不用说了，强调了很多遍了。{region}需替换为您物联网平台服务所在地域的代码。可以参考地域

Client ID

MQTT_Device|securemode=3,signmethod=hmacsha1|，表示TCP直连（不加密）
② MQTT_Device|securemode=2,signmethod=hmacsha1|，表示TLS直连（加密）

1）{clientId}为设备的ID信息。可取任意值，我这里等同于DeviceName，长度在64字符以内。建议使用设备的MAC地址或SN码。
2）securemode为安全模式，TCP直连模式设置为securemode=3，TLS直连为securemode=2。
3）signmethod为算法类型，支持hmacmd5和hmacsha1（基本上用这个）。
输入Client ID信息后，请勿单击Generate

User Credentials

设置用户名和密码 

 User Name固定格式：{YourDeviceName}&{YourPrductKey}

Password：这个就得用工具生成了，工具下载地址

下载解压后打开里面的html网页，按照图片输入自己的信息就可以了

securemode 

直连模式的我们不需要考虑这个，配置完后保存即可

 4、MQTT(发布和订阅)

 MQTT协议不熟悉的以后有机会再讲吧，目前其他博主介绍的更详细。8266也用类似的方法接入阿里云平台。

//esp8266代码
#include <ESP8266WiFi.h>
#include <ArduinoJson.h>
#include <PubSubClient.h>
#include <WiFiClientSecure.h>

const char* WIFI_SSID     = "Redmi K50 Ultra"; // WiFi账号密码
const char* WIFI_PASSWORD = "20000906"; // WiFi密码

/******************产品/设备配置(每个人需要根据自己的产品设备信息去动态更换)**********************/
#define PRODUCT_KEY "xxxxxxx"  //产品key  从产品详情获取
#define DEVICE_NAME "xxxx"  //设备deviceName  从设备详情获取
// 服务端相关
#define MQTT_SERVER   PRODUCT_KEY ".iot-as-mqtt.cn-shanghai.aliyuncs.com" //阿里云MQTT服务地址
#define MQTT_PORT     1883                                               //MQTT服务端口
// 校验三元组
#define MQTT_CLIENT_ID  DEVICE_NAME "|securemode=3,signmethod=hmacsha1|" //mqtt clientid
#define MQTT_USERNAME   DEVICE_NAME "&" PRODUCT_KEY                      //mqtt username
#define MQTT_PASSWORD   "4E48894AB34F7B0FCB83EA0C19F8FB46EC592CD9"       //mqtt password 通过生成工具获得
// 相关主题 自定义一个主题
#define TOPIC1 "/" PRODUCT_KEY "/" DEVICE_NAME "/user/setled"
/*************************************************************************************************/

void mqtt_callback (char* topic, byte* payload, unsigned int length);
void doWiFiTick();
void connect_wifi();
void connectToMqtt();
const __FlashStringHelper* connectErrorToString(int8_t code);

WiFiClient client;
PubSubClient mqttclient(MQTT_SERVER, MQTT_PORT, &mqtt_callback, client);

bool ICACHE_FLASH_ATTR connectHTTPS() {
  Serial.print("connecting to ");
  Serial.println(MQTT_SERVER);
  if (!client.connect(MQTT_SERVER, MQTT_PORT)) {
    Serial.println(F("connection failed"));
    return false;
  }
  else {
    Serial.println(F("connection succeed"));
    return true;
  }
}

void setup() {
  // put your setup code here, to run once:
  delay(2000);
  Serial.begin(115200);
  pinMode(LED_BUILTIN, OUTPUT);
  Serial.println("");
}

void loop() {
  // put your main code here, to run repeatedly:
  ESP.wdtFeed();
  doWiFiTick();
  if (WiFi.status() == WL_CONNECTED) {
    connectToMqtt();
    mqttclient.loop();
  }
  delay(2000);
}

/**
 * 功能：连接到WiFi热点
 */
void connect_wifi() {
  WiFi.disconnect();
  WiFi.mode(WIFI_STA);
  WiFi.begin(WIFI_SSID, WIFI_PASSWORD);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.print(F("\nWiFi connected to "));
  Serial.println(WIFI_SSID);
  Serial.print(F("IP address: "));
  Serial.println(WiFi.localIP());
}

/**
 * 功能：连接到Mqtt
 */
void connectToMqtt() {
  if (mqttclient.connected()) {
   return;
  }

  Serial.print(F("Connecting to MQTT... "));

  int8_t ret;
  uint8_t retries = 3;

  while (!mqttclient.connect(MQTT_CLIENT_ID, MQTT_USERNAME,MQTT_PASSWORD)) { // connect will return true for connected
      Serial.println(connectErrorToString(mqttclient.state()));
      Serial.println(F("Retrying MQTT connection in 5 seconds..."));
      mqttclient.disconnect();
      delay(5000);  // wait 5 seconds
      retries--;
      if (retries == 0) {
        // basically die and wait for WDT to reset me
        while (1);
      }
      yield();
  }
  Serial.println(F("Success!"));
  // 订阅主题
  mqttclient.subscribe(TOPIC1);

}

/**
 * 功能：连接路由心跳函数
 */
void doWiFiTick() {
  static bool taskStarted = false;
  static bool startSTAFlag = false;
  static uint32_t lastWiFiCheckTick = 0;

  if (!startSTAFlag) {
    startSTAFlag = true;

    Serial.print("connect to ap:");
    Serial.println(WIFI_SSID);
    WiFi.disconnect();
    WiFi.mode(WIFI_STA);
    WiFi.begin(WIFI_SSID, WIFI_PASSWORD);
    Serial.printf("Heap size:%d\r\n", ESP.getFreeHeap());
  }

  //未连接1s重连
  if ( WiFi.status() != WL_CONNECTED ) {
    if (millis() - lastWiFiCheckTick > 1000) {
      lastWiFiCheckTick = millis();
      Serial.print(".");
    }
  }
  //连接成功建立
  else {
    if (taskStarted == false) {
      taskStarted = true;
      Serial.print("\r\nGet IP Address: ");
      Serial.println(WiFi.localIP());
    }
  }
}

/**
 * 功能：MQTT回调
 * 参数：
 *   1. topic   主题
 *   2. payload 载体
 *   3. length  载体长度
 */
void mqtt_callback (char* topic, byte* payload, unsigned int length) {
  byte *end = payload + length;
  for (byte *p = payload; p < end; ++p) {
    Serial.print(*((const char *)p));
  }
  Serial.println("");
  parseMqttResponse((char *)payload);
}

/**
 * 解析mqtt数据
 */
void parseMqttResponse(char* payload){
   Serial.println("start parseOneNetMqttResponse");
   StaticJsonBuffer<100> jsonBuffer;
     // StaticJsonBuffer 在栈区分配内存   它也可以被 DynamicJsonBuffer（内存在堆区分配） 代替
     // DynamicJsonBuffer  jsonBuffer;
   JsonObject& root = jsonBuffer.parseObject(payload);

     // Test if parsing succeeds.
   if (!root.success()) {
       Serial.println("parseObject() failed");
       return ;
   }

   String deviceName = root["dn"];
   int status = root["s"];

   if(strcmp(DEVICE_NAME,deviceName.c_str())== 0){
        if (status == 1) {
            digitalWrite(LED_BUILTIN, LOW);
        } else {
            digitalWrite(LED_BUILTIN, HIGH);
        }
    }
}

/**
 * 功能：打印错误
 * 参数：
 *   1. code   错误码
 */
const __FlashStringHelper* connectErrorToString(int8_t code) {
   switch (code) {
      case 1: return F("The Server does not support the level of the MQTT protocol requested");
      case 2: return F("The Client identifier is correct UTF-8 but not allowed by the Server");
      case 3: return F("The MQTT service is unavailable");
      case 4: return F("The data in the user name or password is malformed");
      case 5: return F("Not authorized to connect");
      case 6: return F("Exceeded reconnect rate limit. Please try again later.");
      case 7: return F("You have been banned from connecting. Please contact the MQTT server administrator for more details.");
      case -1: return F("Connection failed");
      case -2: return F("Failed to subscribe");
      case -3: return F("Connection Lost");
      case -4: return F("Connection Timeout");
      default: return F("Unknown error");
   }
}

 这样8266也连接上了阿里云平台，我们通过8266订阅主题，然后MQTT.fx发布信息从而控制8266的LED亮灭。

现在就是往阿里云的mqtt服务器添加topic，让esp8266可以订阅这个topic，mqtt.fx客户端可以对这个topic发布控制信息，esp8266解析这个订阅信息从而控制灯的亮灭。

待续