14.3.4 接口引用 vs 泛型接口约束
在上一个例子中，我定义了一个泛型类，可以与实现特定接口的任何对象一起使用。我也可以通过创建基于接口引用的标准（非泛型）类来获得类似的效果。实际上，我可以定义一个类，如下所示（也是 IntfConstraint 示例的一部分）：
type
TPlainInftClass = class
private
FVal1, FVal2: IGetValue;
public
procedure Set1(Val: IGetValue);
procedure Set2(Val: IGetValue);
function GetMin: Integer;
function GetAverage: Integer;
procedure IncreaseByTen;
end;
这两种方法有什么不同呢？第一个不同点是，在上面的类中，只要它们的类都实现了给定的接口，就可以向setter方法传递两个不同类型的对象，而在泛型版本中，只能传递给定类型的对象或该类型的派生对象（传递给泛型类的任何给定实例）。因此，泛型版本在类型检查方面更为保守和严格。
在我看来，关键的区别在于，使用基于接口的版本意味着 Object Pascal 的引用计数机制会起作用，而使用泛型版本，则是处理给定类型的普通对象，不涉及引用计数。此外，泛型版本可以具有多个约束，如构造函数约束，并允许您使用各种泛型函数（例如查询泛型类型的实际类型），而使用接口时则无法引用基类 TObject中的方法。
换句话说，使用带有接口约束的泛型类可以有接口的好处，而不会带来麻烦。不过，值得注意的是，在大多数情况下，这两种方法是等价的，而在另一些情况下，基于接口的解决方案则更为灵活。
14.3.5 默认构造函数约束
还有另一种可能的泛型类型约束，称为默认构造函数或无参数构造函数。如果你需要调用默认构造函数来创建泛型类型的新对象，例如用于填充列表，你可以使用这个约束。从理论上讲并根据文档描述，编译器只允许在有默认构造函数的类型中使用该约束。实际上，如果不存在默认构造函数，编译器就会放任不管，调用 TObject 的默认构造函数。
带有构造函数约束的泛型类可以这样写（这个例子是从 IntfConstraint 例子中提出来的）：
type
TConstrClass<T: class, constructor> = class
private
FVal: T;
public
constructor Create;
function Get: T;
end;
**注解：**你也可以在没有 class 约束的情况下指定构造函数约束，因为有构造函数意味着该类型是一个类。列出它们两者使代码更可读。
有了这个声明，你就可以使用构造函数创建一个内部泛型对象，而不需要事先知道它的实际类型，然后写下：
constructor TConstrClass<T>.Create;
begin
FVal := T.Create;
end;
我们如何使用这个泛型类，实际规则是什么？在下一个示例中，我定义了两个类，一个是默认的无参数构造函数，另一个是有一个参数的单构造函数：
type
TSimpleConst = class
public
FValue: Integer;
constructor Create; // 设置 Value 为 10
end;
TParamConst = class
public
FValue: Integer;
constructor Create(I: Integer); // 设置 Value 为 I
end;
正如我之前提到的，在理论上，你应该只能使用第一个类，然而在实际中，你可以使用两个类：
var
ConstructObj: TConstrClass<TSimpleConst>;
ParamCostObj: TConstrClass<TParamConst>;
begin
ConstructObj := TConstrClass<TSimpleConst>.Create;
Show('Value 1: ' + IntToStr(ConstructObj.Get.FValue));
ParamCostObj := TConstrClass<TParamConst>.Create;
Show('Value 2: ' + IntToStr(ParamCostObj.Get.FValue));
end;
这段代码的输出是：
Value 1: 10
Value 2: 0
事实上，第二个对象从未被初始化。如果你调试应用程序并跟踪代码，你会看到对 TObject.Create 的调用（我认为这是错误的）。请注意，如果你直接调用：
with TParamConst.Create do
编译器将（正确地）引发错误：
[DCC Error] E2035 Not enough actual parameters
注解： 即使直接调用 TParamConst.Create 会在编译时失败（如此处所述），使用类引用或任何其他形式的间接调用将成功；这可能解释了构造函数约束的影响。
