Michael.W基于Foundry精读Openzeppelin第43期——Pausable.sol

0. 版本

[openzeppelin]：v4.8.3，[forge-std]：v1.5.6

0.1 Pausable.sol

Github: https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v4.8.3/contracts/security/Pausable.sol

Pausable库实现了功能函数紧急关停机制，可以继承该合约并使管理员账户来调控合约的开关。合约内有两个修饰器whenNotPaused和whenPaused，可以根据业务需求将其修饰在对应的函数上来进行开放或关停状态下的访问限制。

1. 目标合约

继承Pausable合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/src/security/MockPausable.sol

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.0;

import "openzeppelin-contracts/contracts/security/Pausable.sol";

contract MockPausable is Pausable {
   
    constructor() Pausable() {
   }

    function pause() external {
   
        _pause();
    }

    function unpause() external {
   
        _unpause();
    }

    function doSomethingWhenPaused() external whenPaused {
   }

    function doSomethingWhenNotPaused() external whenNotPaused {
   }
}

全部foundry测试合约：

Github: https://github.com/RevelationOfTuring/foundry-openzeppelin-contracts/blob/master/test/security/Pausable.t.sol

2. 代码精读

2.1 constructor()

设置合约为非暂停态。

    // 合约转为暂停态时抛出的事件
    event Paused(address account);

    // 合约转为非暂停态时抛出的事件
    event Unpaused(address account);

	// 用于合约暂停状态的flag变量
    bool private _paused;

	// 初始化函数
    constructor() {
   
        _paused = false;
    }

2.2 paused() && _pause() internal && _unpause() internal

• paused()：查询当前合约是否为暂停状态。如果处于暂停状态返回true，否则返回false；
• _pause() internal：将合约从非暂停状态转为暂停状态。注：要求触发该方法时，合约必须为非暂停状态；
• _unpause() internal：将合约从暂停状态转为非暂停状态。注：要求触发该方法时，合约必须为暂停状态。

    function paused() public view virtual returns (bool) {
   
        // 返回合约暂停状态的flag变量值
        return _paused;
    }
    
    function _pause() internal virtual whenNotPaused {
   
        // 暂停状态flag变为true
        _paused = true;
        // 抛出事件
        emit Paused(_msgSender());
    }

    function _unpause() internal virtual whenPaused {
   
       	// 暂停状态flag变为false
        _paused = false;
        // 抛出事件
        emit Unpaused(_msgSender());
    }

foundry代码验证：

contract PausableTest is Test {
   
    MockPausable private _testing = new MockPausable();

    event Paused(address account);
    event Unpaused(address account);

    function test_PauseAndUnpauseAndPaused() external {
   
        assertFalse(_testing.paused());

        // 1. test _pause()
        vm.expectEmit(false, false, false, true, address(_testing));
        emit Paused(address(this));
        _testing.pause();
        assertTrue(_testing.paused());

        // revert if the contract is on paused
        vm.expectRevert("Pausable: paused");
        _testing.pause();

        // 2. test _unpause()
        vm.expectEmit(false, false, false, true, address(_testing));
        emit Unpaused(address(this));
        _testing.unpause();
        assertFalse(_testing.paused());

        // revert if the contract is on not paused
        vm.expectRevert("Pausable: not paused");
        _testing.unpause();
    }
}

2.3 modifier whenNotPaused() && modifier whenPaused()

• modifier whenNotPaused()：修饰器，被修饰的方法只能在合约处于非暂停状态时才可以调用；
• modifier whenPaused()：修饰器，被修饰的方法只能在合约处于暂停状态时才可以调用。

    modifier whenNotPaused() {
   
    	// 调用_requireNotPaused()方法，检查合约当前必须处于非暂停状态，否则revert
        _requireNotPaused();
        _;
    }

    modifier whenPaused() {
   
        // 调用_requirePaused()方法，检查合约当前必须处于暂停状态，否则revert
        _requirePaused();
        _;
    }

    // 如果合约处于暂停状态，直接revert
    function _requireNotPaused() internal view virtual {
   
        // 如果_paused为true，revert
        require(!paused(), "Pausable: paused");
    }

   	// 如果合约处于非暂停状态，直接revert
    function _requirePaused() internal view virtual {
   
        // 如果_paused为false，revert
        require(paused(), "Pausable: not paused");
    }

foundry代码验证：

contract PausableTest is Test {
   
    MockPausable private _testing = new MockPausable();

    function test_WhenNotPausedAndWhenPaused() external {
   
        assertFalse(_testing.paused());
        // pass modifier 'whenNotPaused'
        _testing.doSomethingWhenNotPaused();

        // not pass modifier 'whenPaused'
        vm.expectRevert("Pausable: not paused");
        _testing.doSomethingWhenPaused();

        // pause the contract
        _testing.pause();
        assertTrue(_testing.paused());

        // pass modifier 'whenPaused'
        _testing.doSomethingWhenPaused();

        // not pass modifier 'whenPaused'
        vm.expectRevert("Pausable: paused");
        _testing.doSomethingWhenNotPaused();
    }
}

ps:
本人热爱图灵，热爱中本聪，热爱V神。
以下是我个人的公众号，如果有技术问题可以关注我的公众号来跟我交流。
同时我也会在这个公众号上每周更新我的原创文章，喜欢的小伙伴或者老伙计可以支持一下！
如果需要转发，麻烦注明作者。十分感谢！

公众号名称：后现代泼痞浪漫主义奠基人