ESP8266 驱动WS2812B

2024-07-16 04:48:03
开发
26

安装Adafruit_NeoPixel

点击安装之后，等待安装完成即可

测试程序

操作流程：文件=>示例=>Adafruit_NeoPixel =>simpleAdafruit_NeoPixel

可以根据需求选择不同的项目进行不同效果展示

项目实例

流水灯

#include <Adafruit_NeoPixel.h>
#define PIN 0	//GPIO0
#define NUMPIXELS 36//流水灯数量

//创建一个Adafruit_NeoPixel对象，参数分别是LED数量、引脚号和颜色顺序及数据频率
Adafruit_NeoPixel pixels = Adafruit_NeoPixel(NUMPIXELS, PIN, NEO_GRB + NEO_KHZ800);
 
void setup()
{
    pixels.begin();
}
 
void loop()
{
    waterled(10);         //流水灯
}


void waterled(int wait){
    for(int i=0;i<NUMPIXELS;i++)
    {
        pixels.setPixelColor(i, pixels.Color(0,150,150));	//青
        pixels.show();
        delay(wait);
    }
 
    for(int i=0;i<NUMPIXELS;i++){
        pixels.setPixelColor(i, pixels.Color(150,150,0));	//黄
        pixels.show();
        delay(wait);
    }

    for(int i=0;i<NUMPIXELS;i++){
        pixels.setPixelColor(i, pixels.Color(255,0,0));		//红
        pixels.show();
        delay(wait);
    }

}

硬件连接：数据线连接到GPIO0、GND连接板卡的GND、VCC可以连接板卡的VCC，也可单独接入5V供电

项目效果：36个LED依次点亮，颜色变化顺序为青、黄、红。每颗LED之间的点亮间隔为10ms

彩虹灯

#include <Adafruit_NeoPixel.h>
#define PIN 0	//GPIO0
#define NUMPIXELS 35//流水灯数量

//创建一个Adafruit_NeoPixel对象，参数分别是LED数量、引脚号和颜色顺序及数据频率
Adafruit_NeoPixel pixels = Adafruit_NeoPixel(NUMPIXELS, PIN, NEO_GRB + NEO_KHZ800);
 
void setup()
{
    pixels.begin();
}
 
void loop()
{ 
    rainbow(10);             // 彩虹灯
}

void rainbow(int wait) {
    for(long firstPixelHue = 0; firstPixelHue < 5*65536; firstPixelHue += 256) {
        pixels.rainbow(firstPixelHue);
        pixels.show();
        delay(wait);
    }
}

pixels.rainbow(firstPixelHue)调用Adafruit_NeoPixel库中的rainbow方法来设置每个像素的颜色，创建彩虹效果。其中firstPixelHue表示颜色的色调值。

色调值（Hue）是色彩模型中的一个属性，用来表示颜色的基本属性。色调值是HSL（色调、饱和度、亮度）和HSV（色调、饱和度、明度）色彩模型的一部分。

在这些色彩模型中，色调值通常表示为0到360度的角度，表示颜色在色环中的位置。常见的色调值对应的颜色如下：

0度：红色
60度：黄色
120度：绿色
180度：青色
240度：蓝色
300度：紫色

在Adafruit NeoPixel库中，色调值是一个从0到65535的整数，而不是0到360的角度。这个范围允许更精细的颜色过渡。色调值从0到65535会覆盖整个色环，因此每增加256的色调值会逐渐改变颜色，创造出平滑的渐变效果。

呼吸灯

#include <Adafruit_NeoPixel.h>
#ifdef __AVR__
#include <avr/power.h>
#endif
#define PIN 0

Adafruit_NeoPixel strip = Adafruit_NeoPixel(36, PIN, NEO_GRB + NEO_KHZ800);

void colorWipe(uint32_t c, uint8_t wait) {
        for(uint16_t i=0; i<strip.numPixels(); i++) {
                strip.setPixelColor(i, c);
                strip.show();
                delay(wait);
        }
}

uint32_t Wheel(byte WheelPos) {
    WheelPos = 255 - WheelPos;
    if(WheelPos < 85) {
        return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
    }
    if(WheelPos < 170) {
        WheelPos -= 85;
        return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
    }
    WheelPos -= 170;
    return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
}

void rainbow(uint8_t wait) {
    uint16_t i, j;

    for(j=0; j<256; j++) {
        for(i=0; i<strip.numPixels(); i++) {
            strip.setPixelColor(i, Wheel((i+j) & 255));
        }
        strip.show();
        delay(wait);
    }
}

void rainbowCycle(uint8_t wait) {
    uint16_t i, j;

    for(j=0; j<256*5; j++) { // 5 cycles of all colors on wheel
        for(i=0; i< strip.numPixels(); i++) {
            strip.setPixelColor(i, Wheel(((i * 256 / strip.numPixels()) + j) & 255));
        }
        strip.show();
        delay(wait);
    }
}

void theaterChase(uint32_t c, uint8_t wait) {
    for (int j=0; j<10; j++) {    //do 10 cycles of chasing
        for (int q=0; q < 3; q++) {
            for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
                strip.setPixelColor(i+q, c);        //turn every third pixel on
            }
            strip.show();

            delay(wait);

            for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
                strip.setPixelColor(i+q, 0);
            }
        }
    }
}

void theaterChaseRainbow(uint8_t wait) {
    for (int j=0; j < 256; j++) {
        for (int q=0; q < 3; q++) {
            for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
                strip.setPixelColor(i+q, Wheel( (i+j) % 255));        //turn every third pixel on
            }
            strip.show();

            delay(wait);

            for (uint16_t i=0; i < strip.numPixels(); i=i+3) {
                strip.setPixelColor(i+q, 0);                //turn every third pixel off
            }
        }
    }
}

void clear(){
    for(uint16_t i=0; i<strip.numPixels(); i++) {
        strip.setPixelColor(i, 0); 
        delay(10);
    }
}

void meteor(uint8_t red, uint8_t green, uint8_t blue, uint8_t wait) {
    const uint8_t num = 15;
    uint8_t max_color = red;
    if(green > max_color)
        max_color = green;
    if(blue > max_color)
        max_color = blue;
    uint8_t instance = (max_color-200)/num;
    for(uint16_t i=0; i<strip.numPixels() + num; i++) {
        for(uint8_t j = 0; j < num; j ++){
            if(i - j >= 0 && i - j < strip.numPixels()){
                int red_after = red - (instance * j);
                int green_after = green - (instance * j);
                int blue_after = blue - (instance * j);
                
                if(j>=1){
                    red_after -= 200;
                    green_after -= 200;
                    blue_after -= 200;
                }
                strip.setPixelColor(i - j, strip.Color(red_after >= 0 ? red_after : 0, green_after >= 0 ? green_after : 0, blue_after >= 0 ? blue_after : 0));
            }
        }
        if(i - num >= 0 && i-num < strip.numPixels())
            strip.setPixelColor(i-num, 0); 

        strip.show();
        delay(wait);
    }
}

void meteor_overturn(uint8_t red, uint8_t green, uint8_t blue, uint8_t wait) {

    const uint8_t num = 15;
    uint8_t max_color = red;
    if(green > max_color)
        max_color = green;
    if(blue > max_color)
        max_color = blue;
    uint8_t instance = (max_color-200)/num;
    for(int i=strip.numPixels() - 1; i>=-num; i--) {
        for(uint8_t j = 0; j < num; j ++){
            if(i + j >= 0 && i + j < strip.numPixels()){
                int red_after = red - instance * j;
                int green_after = green - instance *  j;
                int blue_after = blue - instance *  j;
                if(j>=1){
                    red_after -= 200;
                    green_after -= 200;
                    blue_after -= 200;
                }
                strip.setPixelColor(i + j, strip.Color(red_after >= 0 ? red_after : 0, green_after >= 0 ? green_after : 0, blue_after >= 0 ? blue_after : 0));
            }
        }
        if(i + num >= 0 && i+num < strip.numPixels())
            strip.setPixelColor(i+num, 0); 

        strip.show();
        delay(wait);
    }
}




void setup() {
    #if defined (__AVR_ATtiny85__)
        if (F_CPU == 16000000) clock_prescale_set(clock_div_1);
    #endif

    strip.begin();
    strip.setBrightness(100);
    strip.show(); // Initialize all pixels to 'off'
}

void loop() {
    // 递进渐变
    // colorWipe(strip.Color(255, 0, 0), 20); // Red
    // colorWipe(strip.Color(0, 255, 0), 20); // Green
    // colorWipe(strip.Color(0, 0, 255), 20); // Blue

    // 交叉突变
    // theaterChase(strip.Color(127, 127, 127), 50); // White
    // theaterChase(strip.Color(127, 0, 0), 50); // Red
    // theaterChase(strip.Color(0, 0, 127), 50); // Blue

    // 整体渐变
    rainbow(12);

    // 呼吸灯效果(rainbow进阶版本)
    // rainbowCycle(10);
 
    // 交叉突变 + 整体渐变(rainbow进阶版本)
    // theaterChaseRainbow(50);

    // 流星
    // clear();
    // meteor(255, 0, 0, 10);
    // meteor_overturn(255, 0, 0, 10);
}

原文地址:https://blog.csdn.net/Wangguang_/article/details/140451858 本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若转载，请注明出处：https://www.suanlizi.com/kf/1812952286218031104.html 如若内容造成侵权/违法违规/事实不符，请联系《酸梨子》网邮箱：1419361763@qq.com进行投诉反馈，一经查实，立即删除！

阅读全部